<%@ LANGUAGE="VBSCRIPT" %>
<% PageStrings = "18, 51, 52, 53, 54, 55, 56, 57, 58, 59, 60, 61, 62, 63, 64, 65, 68, 69, 70, 71, 121, 164, 222" %>
<%
 
thispage="basket"
%>
<!--#include file="../includes/configuration.asp"-->
<!--#include file="../includes/lock_shop.asp"-->
<!--#include file="../includes/init.asp"-->
<!--#include file="../includes/functs.asp"-->
<%
aryCart2 = aryCart
 
Function AddToExistingItem(V,Q,aryCart2)
	For comp = 0 to Application(HASHKEYNUMBERXYZ & "basketmaxcapacity")
		If aryCart2(comp,1) = V then
			aryCart2(comp,2) = aryCart2(comp,2) + Q
			duplicate = 1
		end if
	next
	AddToExistingItem = aryCart2
End Function
 
Function AddNewItemLine(V,Q,aryCart2)
		aryCart2(iCount,1) = V
		aryCart2(iCount,2) = Q
	iCount=iCount+1
	AddNewItemLine = aryCart2
End Function
 
Function TagRowForDeletion(R,aryCart2)
		For comp = 0 to Application(HASHKEYNUMBERXYZ & "basketmaxcapacity")
			If aryCart2(comp,1) = R then
				aryCart2(comp,1) = ""
				aryCart2(comp,2) = ""
				iCount = iCount - 1
			end if
		next
	TagRowForDeletion = aryCart2
End Function
 
Function SquashOutSpaces(aryCart2)
		For comp = 0 to (Application(HASHKEYNUMBERXYZ & "basketmaxcapacity")-1)
			If aryCart2(comp,2) = "" then
				aryCart2(comp,1) = aryCart2(comp + 1,1)
				aryCart2(comp,2) = aryCart2(comp + 1,2)
				aryCart2(comp + 1,1) = ""
				aryCart2(comp + 1,2) = ""
			end if
		next
	SquashOutSpaces = aryCart2
End Function
 
duplicate = 0
 
R = Request.QueryString("R")
V = Request.QueryString("V")
Q = Request.Querystring("Q")

strReturnURL = replace(replace(Request.QueryString("U"),"questionmark","?"),"ampersand","&")
strSpeedMessage = Request.Querystring("strSpeedMessage")
numLineCount = Request.Querystring("numLineCount")
if Q="" then Q=1
Q=Q*1

product = Request.QueryString("product")
If Request.Form("V")<>"" then
	V = Request.Form("V")
end if

If request.querystring("FF") = "yes" then
V = "refresh"
 
	for tt = 1 to iCount
		aryCart2(tt-1,2) = (Request.querystring("T" & tt))
		if Not IsNumeric(aryCart2(tt-1,2)) then
			aryCart2(tt-1,2) = ""
			iCount = iCount - 1
		end if
		if aryCart2(tt-1,2) = "0" then
			aryCart2(tt-1,2) = ""
			iCount = iCount - 1
		end if
		If IsNumeric(aryCart2(tt-1,2)) then
			aryCart2(tt-1,2) = Int(aryCart2(tt-1,2))
			If aryCart2(tt-1,2) < 0 then
				aryCart2(tt-1,2) = ""
				iCount = iCount - 1
			end if
		end if
	next
end if
 
If V <> "refresh" and V <> "remove" then
	If strReturnURL<>"" then
		strReturnURL = strReturnURL & "&strShowBackLink=n"
 
		For SpeedRows = 1 to numLineCount
			tempV = Request.querystring("V" & SpeedRows)
			tempQ = Request.querystring("Q" & SpeedRows)*1
			If tempV<>"" then
				aryCart2 = AddToExistingItem(tempV,tempQ,aryCart2)
				If duplicate = 0 then
					aryCart2 = AddNewItemLine(tempV,tempQ,aryCart2)
				end if
			end if
			duplicate = 0
		Next
	else
		aryCart2 = AddToExistingItem(V,Q,aryCart2)
		If duplicate = 0 then
			aryCart2 = AddNewItemLine(V,Q,aryCart2)
		end if
	end if
end if

If V = "remove" then
	aryCart2 = TagRowForDeletion(R,aryCart2)
end if
For y = 1 to Application(HASHKEYNUMBERXYZ & "basketmaxcapacity")
	aryCart2 = SquashOutSpaces(aryCart2)
next
 
%>
<!--#include file="../includes/basketcookie.asp"-->
<%
 
If len(Request.Querystring("Empty")) > 0 then response.redirect("empty_bask.asp")
If len(Request.Querystring("Checkout")) > 0 then response.redirect("shipto.asp")
If len(Request.Querystring("Enquire")) > 0 then response.redirect("shipto.asp?m=enquiry")
 
%>
<!--#include file="../includes/makepage.asp"-->
<%
 
If quantitiesadjusted="yes" then strReturnURL=""
 
If Application(HASHKEYNUMBERXYZ & "showbasket") = "n" AND strReturnURL<>"" then response.redirect(strReturnURL)
 
Call ReadFromTemplate(templatelocation,aryPageTemplate,strBasketHTML,strCategoryListHTML)
 
If IsNumeric(Application(HASHKEYNUMBERXYZ & "showbasket")) AND strReturnURL<>"" then strMetaRefresh="<meta http-equiv='refresh' content='" & Application(HASHKEYNUMBERXYZ & "showbasket") & ";URL=" & strReturnURL & "'>"
If strSpeedMessage<>"" then strMetaRefresh=""

aryPageTemplate(0) = Replace(aryPageTemplate(0),"<head>","<head>" & vbcrlf & strMetaRefresh)
 
response.write(aryPageTemplate(0))
%>
<table border="0" cellpadding="5" cellspacing="0" width="100%">
<tr>
	<td class="largebold"><% WriteString("PageTitle_ShoppingBasket") %></td>
</tr>
</table>
<%
 
If strMetaRefresh<>"" then %>
<table border="0" cellpadding="5" cellspacing="0" width="100%">
<tr>
	<td class="medbold"><% WriteString("ContentText_ItemsAdded") %><br><br></td>
</tr>
<tr>
	<td class="largebold"><% WriteString("ContentText_PleaseWait") %></td>
</tr>
</table>
<% else
If iCount = 0 then %>
<table border="0" cellpadding="5" cellspacing="0" width="100%">
<% if V="speedorder" AND strSpeedMessage<>"" then %>
<tr>
	<td class="medboldalt"><% =strSpeedMessage %></td>
</tr>
<% end if %>
<tr>
	<td class="medbold"><% WriteString("ContentText_BasketEmpty") %></td>
</tr>
</table><br><br>
<% else %>
<form method="GET" name="theform" action="basket.asp">
<input type="hidden" name="show" value="yes">
<input type="hidden" name="FF" value="yes">
<table border="0" cellpadding="5" cellspacing="0" width="100%" class="mainpage">
<tr>
	<td><table border="0" cellpadding="1" cellspacing="0" width="100%">
	<tr>
		<td width="30%"></td>
		<td  colspan="2" align="right" class="smallboldtabletop" width="27%"><% WriteString("ContentText_ExTax") %> (<% =Application(HASHKEYNUMBERXYZ & "currencyunit") %>)&nbsp;</td>
		<td align="right" class="smallboldtabletop" width="15%"><% WriteString("ContentText_IncTax") %> (<% =Application(HASHKEYNUMBERXYZ & "currencyunit") %>)&nbsp;</td>
		<td align="right" class="smallboldtabletop" width="14%"><% WriteString("ContentText_Qty") %></td>
		<td width="11%"></td>
	</tr>
	<%
	If iCount>0 then
		for lp = 1 to iCount
 
		If DBType = "mysql" Then
			theQuery = "SELECT * FROM tbl_Versions INNER JOIN tbl_Products ON tbl_Versions.V_Product = tbl_Products.P_ID INNER JOIN tbl_ProductProdTypeLink ON tbl_Products.P_ID = tbl_ProductProdTypeLink.PPT_ProductID INNER JOIN tbl_Prodtype ON tbl_ProductProdTypeLink.PPT_ProdTypeID = tbl_Prodtype.PT_ID INNER JOIN tbl_TaxRates ON tbl_Versions.V_Tax = tbl_TaxRates.T_ID WHERE V_ID=" & aryCart2(lp-1,1)
		Else
			theQuery = "SELECT * FROM (tbl_Versions INNER JOIN ((tbl_Products INNER JOIN tbl_ProductProdTypeLink ON tbl_Products.P_ID = tbl_ProductProdTypeLink.PPT_ProductID) INNER JOIN tbl_Prodtype ON tbl_ProductProdTypeLink.PPT_ProdTypeID = tbl_Prodtype.PT_ID) ON tbl_Versions.V_Product = tbl_Products.P_ID) INNER JOIN tbl_TaxRates ON tbl_Versions.V_Tax = tbl_TaxRates.T_ID WHERE V_ID=" & aryCart2(lp-1,1)
		End If
		Call ExecuteSQL(theQuery,cursortype,rs_main)

		numItemQuantity = aryCart2(lp-1,2)

		If InStr(strAdjustedQuantity,"z" & rs_main("V_ID") & "z")>0 then
			bgcolor="mainpageversionhighlight"
		else
			bgcolor="mainpagetableline"
		end if
	%>
	<!--#include file="../includes/price_basic.asp"-->
	<tr class="mainpagetableline2">
		<td colspan="6" class="medboldtable"><% response.write(rs_main("P_Name")) %></td>
	</tr>
	<tr class="<% =bgcolor %>">
		<td valign="middle" class="smalltexttable" width="30%"><a class="table" href="prod.asp?product=<% =rs_main("P_ID") %>&V=<% =rs_main("V_ID") %>&ph=basket"><% response.write(rs_main("V_Name")) %></a></td>
		<td valign="middle" class="smalltexttable" width="15%"><% response.write(rs_main("V_CodeNumber")) %></td>

<%
 
If Application(HASHKEYNUMBERXYZ & "pricesinctax") = "y" then
	If Application(HASHKEYNUMBERXYZ & "showtaxdisplay") = "y" then
	%>
			<td align="right" class="smalltexttable"><% =Pounds(numItemPriceExTax) %>&nbsp;</td>
			<td align="right" class="smallboldtable"><% =Pounds(numItemPriceIncTax) %>&nbsp;</td>
	<% Else %>
			<td align="right" class="smallboldtable" colspan="2"><% =Pounds(numItemPriceIncTax) %>&nbsp;</td>
	<% End if
Else
 
	%>
			<td align="right" class="smallboldtable"><% =Pounds(numItemPriceExTax) %>&nbsp;</td>
			<td align="right" class="smalltexttable"><% =numTax*100 %>&nbsp;</td>

	<% End if %>

		<td align="right" valign="middle"><input type="text" value="<% =numItemQuantity %>" name="T<% response.write(lp) %>" size="3"></td>
		<td align="right" valign="middle" class="smalltexttable"><a href="basket.asp?R=<% =rs_main("V_ID") %>&V=<% response.write("remove") %>" class="table"><% WriteString("FormButton_Remove") %></a></td>
	</tr>
	<%
	rs_main.Close
	next
	end if
	%>
	</table></td>
</tr>
</table>
<table border="0" cellpadding="3" cellspacing="0" width="100%">
<% if V="speedorder" AND strSpeedMessage<>"" then %>
<tr>
	<td class="medboldalt"><% =strSpeedMessage%></td>
</tr>
<% end if
If quantitiesadjusted="yes" then %>
<tr>
	<td class="medboldalt"><% WriteString("ContentText_OutOfStock") %></td>
</tr>
<tr>
	<td>&nbsp;</td>
</tr>
<%
end if 
numTotalBasketAmount = Round(numTotalPriceExTax + numTotalTaxAmount,2)
If Application(HASHKEYNUMBERXYZ & "showtaxdisplay") = "y" OR Application(HASHKEYNUMBERXYZ & "pricesinctax")="n" then %>
<tr>
	<td align="right" class="mednormal"><% WriteString("ContentText_OrderAmount")%> = <% =Application(HASHKEYNUMBERXYZ & "currencyunit") & " " & Pounds(numTotalPriceExTax) %></td>
</tr>
<tr>
	<td align="right" class="mednormal"><% WriteString("ContentText_TaxWhereApp")%> = <% =Application(HASHKEYNUMBERXYZ & "currencyunit") & " " & Pounds(numTotalTaxAmount) %></td>
</tr>
<% end if %>
<tr>
	<td align="right" class="medboldalt"><% WriteString("ContentText_Total")%> = <% =Application(HASHKEYNUMBERXYZ & "currencyunit") & " " & Pounds(numTotalBasketAmount) %></td>
</tr>
<tr>
	<td align="right" valign="bottom"><input class="buttonstyle" type="submit" value="<% WriteString("FormButton_Recalculate") %>" tabindex="3" name="Recalculate"><input class="buttonstyle" type="submit" value="<% WriteString("FormButton_EmptyBasket") %>" tabindex="4" name="Empty"><% if Application(HASHKEYNUMBERXYZ & "allowenquiries")="y" then %><input class="buttonstyle" type="submit" value="<% WriteString("FormButton_MakeEnquiry") %>" tabindex="2" name="Enquire"><% end if %>
	<% if (numTotalBasketAmount*1) < Application(HASHKEYNUMBERXYZ & "minorderval")*1 then %><input class="buttonstyle" type="button" tabindex="1" value="<% WriteString("FormButton_Checkout") %>" name="Checkout" onClick="alert('<% WriteString("Popup_OrderBelowMin")%> (<% =Application(HASHKEYNUMBERXYZ & "currencyunit") & Pounds(Application(HASHKEYNUMBERXYZ & "minorderval")) %>)')"><% else %><input class="buttonstyle" type="submit" tabindex="1" value="<% WriteString("FormButton_Checkout") %>" name="Checkout"><% end if %></td>
</tr>
</table>
</form>
<% end if %>
<table border="0" cellpadding="5" cellspacing="0" width="100%">
<tr>
<td></td>
</tr>
</table>
<%
end if
 
response.write(aryPageTemplate(1))
 
DataConn.Close
set DataConn = nothing
%>